BOA TARDE,
A MINHA DÚVIDA EU AINDA NÃO COSEGUI RESOLVER, MAS ACHO QUE FALTA POUCO.
TENHO UM BANCO COM PARTILHADO NUMA REDE, PORÉM TODA VEZ QUE UM NOVO USUÁRIO VAI UTILIZAR O BANCO EU PRECISO IR NA MÁQUINA DELE E CRIAR AQUELE ATALHO "/WROKGRP ...." .
EU VI AQUI NOS POSTS, UM MONTE DE CÓDIGO, PORÉM AINDA NÃO CONSEGUI ENTENDER COMO ABRIR UM BANCO DE DADOS ASSOCIADO AO SEU MDW VIA CÓDIGO, ONDE DEVO PROGRAMAR ISSO?
EXISTE ALGUMA FORMA DE ALTERAR ISSO PELO WINDOWS(REGISTRO) ATRAVÉS DE UM .BAT?
EU CRIO UM SETUPS PRA CADA BANCO QUE FAÇO, E COMO AINDA ESTOU COMEÇANDO, SERIA BOM AUTOMATIZAR AO MÁXIMO QUE PUDER,,,
DESDE JÁ OBRIGADO

leia isto:

Como criar um atalho no desktop ou um grupo no Menu Iniciar para o aplicativo?


Durante o processo de criação dos discos de instalação do seu aplicativo com o Setup Wizard do ODE 97, você é solicitado a adicionar atalhos (Shortcuts) que serão criados pelo programa de instalação como um grupo de programa no Menu Iniciar do microcomputador do usuário. Ao definir o atalho, você deve definir também as propriedades do atalho.

Clique na guia "Database Shortcut Properties", escolha a propriedade Database Shortcut Action Options e defina se o atalho irá abrir (open), compactar (compact) ou reparar e compactar (repair and compact) o banco de dados. Na propriedade Database Command-Line Options, você define os argumentos a serem usados na linha de comando do Access: escolher qual o Workgroup (arquivo .MDW) a ser usado; qual perfil do usuário (Profile) a ser usado no Windows 95 etc.

Contudo, para criar um atalho no Desktop (área de trabalho) do Windows de forma automática, é necessário usar o Visual Basic for Applications (VBA) e arquivos batch (*.bat). A explicação detalhada de como fazê-lo está no artigo 182606 - How to Create a Shortcut on the Desktop with ODE, da Microsoft Knowledge Base.

Outro artigo que ensina a criar atalhos é o 155303: HOWTO: Create Shortcuts (Shell Links) within Windows.

Você pode usar também o Windows Scripting Host (WSH):

Public Sub CreateShortcut(ShortcutLocation As String, PointsTo As String)
' ShortcutLocation is the name and path of your shortcut file
' and should end in ".lnk" -- for simplicity I haven't included the
' code to do this automatically in this routine.
' PointsTo is the location you want your shortcut to point to.
' Noticed that there is no error handling included -- you should
' include your own, as appropriate to your overall application

Dim wshShell As Object
Dim wshShortcut As Object

Set wshShell = CreateObject("WScript.Shell")
' error handling to check for presence of Windows
' Scripting Host goes in here
Set wshShortcut = wshShell.CreateShortcut(ShortcutLocation)
With wshShortcut
.TargetPath = PointsTo
.Save
End With
End Sub

créditos ao JR.


Abraços

e leia isto:


» Como abrir, via código, um banco de dados protegido por outro arquivo MDW (workgroup)?


Uma vez iniciado o Access, você não poderá alterar o arquivo de informações do grupo de trabalho (MDW) atualmente em uso. Desse modo, para abrir um mdb via código que tenha sido protegido por outro arquivo MDW, você precisará utilizar um dos métodos a seguir.

Usando DAO 3.x
É possível abrir um banco de dados protegido pela segurança em nível de usuário, usando outro arquivo MDW (workgroup) diferente do atualmente em uso, por meio do objeto "não documentado" PrivDBEngine da biblioteca DAO 3.x.

Esse objeto é misterioso: não consta do Help do Access (pelo menos até a versão 2000) e somente aparece como um membro oculto do DAO na janela "Pesquisador de Objeto" (F2).

Graças ao grupo de discussão sobre segurança da Microsoft americana, eu descobri o código abaixo que ilustra o uso desse objeto. O código é da Srª Mary Chipman, colaboradora de diversos livros e que ajudou a escrever o Security FAQ. Posteriormente, eu percebi que o código já constava do item 46 (How can I open a database in code that was secured using another workgroup file?) do SECFAQ.

Sub OpenDBWithNewWorkgroupFile(strPathToFile As String, _
strDefaultUser As String, _
strDefaultPwd As String, _
strPathToDatabase As String)
' This function uses the unsupported PrivDBEngine object to
' open a database using a different workgroup information file
' than the one being used as the default. You might do this if
' you want to access data that is in a secured database that uses
' a different workgroup information file.

Dim dbe As PrivDBEngine
Dim wrk As Workspace
Dim dbs As Database

' Return a reference to a new instance of the PrivDBEngine object.
Set dbe = New PrivDBEngine
' Set the SystemDB property to specify the workgroup file.
dbe.SystemDB = strPathToFile
dbe.DefaultUser = strDefaultUser
dbe.DefaultPassword = strDefaultPwd
Set wrk = dbe.Workspaces(0)
' Open the secured database.
Set dbs = wrk.OpenDatabase(strPathToDatabase)
End Sub

O objeto PrivDBEngine, na verdade, cria uma nova instância do motor de banco de dados Jet.
Você poderia obter o mesmo resultado com as linhas de código abaixo:

Dim dbe As DAO.DBEngine
Set dbe = CreateObject("DAO.DBEngine")

A expressão "DAO.DBEngine" deve ser usada para o Jet 3.0 (Access 95). Nas versões mais recentes do Jet, seriam usadas as expressões correspondentes: "DAO.DBEngine.35" para Access 97; ou "DAO.DBEngine.36" para Access 2000.

Usando ADO 2.x
Se você utiliza o ActiveX Data Objects (ADO) do Access 2000 e VB 6.0, passe as informações necessárias à propriedade ConnectionString do objeto Connection. Como demonstração, eu escrevi o código abaixo:

Sub AbreDBProtegido(ByVal strMDWPath As String, _
ByVal strUser As String, ByVal strPwd As String, _
ByVal strMDBPath As String)

On Error GoTo Trata_Err
' Escrito por Joao Rodrigues (JR)
' http://www.accessjr.cjb.net - JUN/2002.

' strMDWPath - caminho do arquivo MDW.
' strUser - nome do usuário.
' strPwd - senha do usuário.
' strMDBPath - caminho do arquivo MDB/MDE.

Dim cnn As New ADODB.Connection, strCnn As String

' Define a string de conexão.
strCnn = "Provider=Microsoft.Jet.OLEDB.4.0;" _
& "Password=" & strPwd & ";User ID=" & strUser _
& ";Data Source=" & strMDBPath & ";Mode=" &adModeReadWrite &";" _
& "Jet OLEDB:System database=" & strMDWPath

cnn.ConnectionString = strCnn
cnn.Open ' UserID e Password poderiam ser passados
' aqui também.

Sai:
If cnn.State = adStateOpen Then
' Aqui você colocaria o código desejado.
' No caso, estou apenas confirmando que
' o banco foi aberto com sucesso.
MsgBox "O arquivo " & strMDBPath _
& " foi aberto com sucesso.", vbInformation, _
"AbreDBProtegido"
cnn.Close ' Libera recursos.
End If
Set cnn = Nothing ' Libera recursos.
Exit Sub

Trata_Err:
MsgBox Err.Description, vbCritical, Err.Source
Resume Sai
End Sub

Para testar o código, abra a janela Verificação imediata (CTRL+G), digite a expressão abaixo e tecle ENTER:

AbreDBProtegido "C:\Temp\Contas.mdw","Pedro","xWh319","C:\Temp\Contas2000.mdb"

Nota: Lembre que a senha é case sensitive; ou seja, o Jet diferencia letras maiúsculas e minúsculas.

também crédito ao Grande Jr


Abraços e retorne se te atendeu!!!

quote:

CreateShortcut(Shortcu

BOM DIA, VI QUE AQUI REALMENTE É O ÚNICO FÓRUM QUE ACHEI ALGUMA RESPOSTA PRA ISSO, COM RELAÇÃO À SEGUNDA RESPOSTA DO ROGÉRIO: EU JÁ HAVIA LIDO ESTA INFORMAÇÃO NO SITE DO JR, PORÉM ONDE VOU COLOCAR ESTES CÓDIGOS, EM UMA MACRO,EM UM FORM, ENFIM ONDE???
OBRIGADO

Leia também...

22. Seja polido. Grosseria não é interessante. Seu teclado tem uma tecla SHIFT. Use-a corretamente. Mensagens e assuntos em maiúsculas são considerados como gritos, rudes e mal educadas. Mensagens com todas as letras em minúscula são difíceis de ler. Assim sendo, desligue a tecla CAPS LOCK e use a tecla SHIFT quendo necessário. Você pode, é claro, usar maiúsculas para enfatizar uma palavra.

Perdoe-me as letras maiúsculas,não era a minha intenção gritar com ninguém.
Afinal o objetivo de um fórum é ajudar uns aos outros,portanto já agradeço a ajuda.
Mas ainda não encerro a minha dúvida já que não conegui achar o software citado: setup wizard ode ....se alguém souber onde conseguir....por favor.